BEGIN "PJOIN"
comment joins several 1 bit/pixel picture files lengthwise into one;
REQUIRE "PIXHDR.SAI[VIS,HPM]" SOURCE_FILE;
REQUIRE "FILHDR.SAI[VIS,HPM]" SOURCE_FILE;
INTEGER NH;

PRINT("How many files?"); NH←CVD(INCHWL);
   BEGIN
   INTEGER I,J,W,WB,H, OUF;
   INTEGER ARRAY POUT[0:117],INF[1:NH];
   INTEGER ARRAY PHD[1:NH,0:10],OHD[0:10]; STRING ARRAY PNAM[1:NH];
   PRSFIL(""); PRSFIL(".VRN");
   W←0; H←0; WB←0;
   FOR I←1 STEP 1 UNTIL NH DO 
      BEGIN
      DO PRINT("File ",I,":") UNTIL (INF[I]←OPNPFL(PNAM[I]←INCHWL,PHD[I,0]))>0;
      WB←WB MAX PHD[I,LNBY];
      W←W MAX PHD[I,LNWD];
      H←H + PHD[I,PCLN];
      END;
   MAKDIM(H,WB,1,OHD[0]);
   PRSFIL("");
   DO PRINT("Output file:") UNTIL (OUF←CREPFL(OHD[0],INCHWL))≥0;
   FOR I←1 STEP 1 UNTIL NH DO
      BEGIN
      INTEGER ARRAY LIN[1:W];
      FOR J←1 STEP 1 UNTIL PHD[I,PCLN] DO
         BEGIN
         ARRYIN(INF[I],LIN[1],PHD[I,LNWD]);
         ARRYOUT(OUF,LIN[1],W);
         END;
      RELEASE(INF[I]);
      END;
   RELEASE(OUF);
   END;
END "PJOIN";